Properly install wasm-bindgen

2025-11-17 03:00:13 +00:00 · 2024-08-14 00:35:27 +01:00
parent a9c16df263
commit e4cec57fe3
3 changed files with 79 additions and 33 deletions
--- a/nix/wasm-bindgen/flake.nix
+++ b/nix/wasm-bindgen/flake.nix
@@ -0,0 +1,50 @@
+{
+  outputs =
+    { self, nixpkgs }:
+    {
+      lib = {
+        build =
+          {
+            system,
+            version,
+            sha256,
+          }:
+          let
+            pkgs = nixpkgs.legacyPackages.${system};
+            wasm-bindgen-src = pkgs.fetchCrate {
+              pname = "wasm-bindgen-cli";
+              inherit version sha256;
+            };
+          in
+          pkgs.rustPlatform.buildRustPackage {
+            name = "wasm-bindgen-cli";
+            buildInputs = [
+              pkgs.curl
+              pkgs.darwin.apple_sdk.frameworks.Security
+            ];
+            src = wasm-bindgen-src;
+            cargoLock = {
+              lockFile = "${wasm-bindgen-src}/Cargo.lock";
+            };
+            doCheck = false;
+          };
+
+        buildFromCargoLock =
+          {
+            system,
+            cargoLockFile,
+            sha256,
+          }:
+          let
+            pkgs = nixpkgs.legacyPackages.${system};
+            cargoLock = pkgs.lib.importTOML cargoLockFile;
+            wasm-bindgen-version =
+              (pkgs.lib.lists.findFirst (x: x.name == "wasm-bindgen") null cargoLock.package).version;
+          in
+          self.lib.build {
+            inherit system sha256;
+            version = wasm-bindgen-version;
+          };
+      };
+    };
+}